nixpkgs/pkgs/development/python-modules/sqlalchemy-continuum/default.nix

{
  lib,
  buildPythonPackage,
  fetchPypi,
  setuptools,
  flask,
  flask-login,
  flask-sqlalchemy,
  psycopg2,
  pymysql,
  pytestCheckHook,
  sqlalchemy,
  sqlalchemy-i18n,
  sqlalchemy-utils,
}:

buildPythonPackage rec {
  pname = "sqlalchemy-continuum";
  version = "1.5.2";
  pyproject = true;

  src = fetchPypi {
    pname = "sqlalchemy_continuum";
    inherit version;
    hash = "sha256-JXHW62FWvIVir7OS/d3rS7MeRKH9HzeIy2Je/i9pbGM=";
  };

  build-system = [ setuptools ];

  dependencies = [
    sqlalchemy
    sqlalchemy-utils
  ];

  optional-dependencies = {
    flask = [ flask ];
    flask-login = [ flask-login ];
    flask-sqlalchemy = [ flask-sqlalchemy ];
    i18n = [ sqlalchemy-i18n ];
  };

  nativeCheckInputs = [
    psycopg2
    pymysql
    pytestCheckHook
  ]
  ++ optional-dependencies.flask
  ++ optional-dependencies.flask-login
  ++ optional-dependencies.flask-sqlalchemy;

  disabledTestPaths = [
    # requires sqlalchemy-i18n, which is incompatible with sqlalchemy>=2
    "tests/test_i18n.py"
  ];

  preCheck = ''
    # Indicate tests that we don't have a database server at hand
    export DB=sqlite
  '';

  pythonImportsCheck = [ "sqlalchemy_continuum" ];

  meta = {
    description = "Versioning and auditing extension for SQLAlchemy";
    homepage = "https://github.com/kvesteri/sqlalchemy-continuum/";
    changelog = "https://github.com/kvesteri/sqlalchemy-continuum/blob/${version}/CHANGES.rst";
    license = lib.licenses.bsd3;
    maintainers = [ ];
  };
}