mirror of
https://github.com/NixOS/nixpkgs.git
synced 2026-03-14 08:26:37 +01:00
567e8dfd8e
This commit was created by a combination of scripts and tools: - an ast-grep script to prefix things in meta with `lib.`, - a modified nixf-diagnose / nixf combination to remove unused `with lib;`, and - regular nixfmt. Co-authored-by: Wolfgang Walther <walther@technowledgy.de>
66 lines
1.6 KiB
Nix
66 lines
1.6 KiB
Nix
{
|
|
stdenv,
|
|
lib,
|
|
fetchPypi,
|
|
buildPythonPackage,
|
|
libvorbis,
|
|
flac,
|
|
libogg,
|
|
libopus,
|
|
opusfile,
|
|
replaceVars,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "pyogg";
|
|
version = "0.6.14a1";
|
|
format = "setuptools";
|
|
|
|
src = fetchPypi {
|
|
pname = "PyOgg";
|
|
inherit version;
|
|
hash = "sha256-gpSzSqWckCAMRjDCzEpbhEByCRQejl0GnXpb41jpQmI=";
|
|
};
|
|
|
|
buildInputs = [
|
|
libvorbis
|
|
flac
|
|
libogg
|
|
libopus
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
libvorbis
|
|
flac
|
|
libogg
|
|
libopus
|
|
opusfile
|
|
];
|
|
|
|
# There are no tests in this package.
|
|
doCheck = false;
|
|
|
|
# patch has dos style eol
|
|
patchFlags = [
|
|
"-p1"
|
|
"--binary"
|
|
];
|
|
patches = [
|
|
(replaceVars ./pyogg-paths.patch {
|
|
flacLibPath = "${flac.out}/lib/libFLAC${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
oggLibPath = "${libogg}/lib/libogg${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
vorbisLibPath = "${libvorbis}/lib/libvorbis${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
vorbisFileLibPath = "${libvorbis}/lib/libvorbisfile${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
vorbisEncLibPath = "${libvorbis}/lib/libvorbisenc${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
opusLibPath = "${libopus}/lib/libopus${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
opusFileLibPath = "${opusfile}/lib/libopusfile${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
})
|
|
];
|
|
|
|
meta = {
|
|
description = "Xiph.org's Ogg Vorbis, Opus and FLAC for Python";
|
|
homepage = "https://github.com/Zuzu-Typ/PyOgg";
|
|
license = lib.licenses.publicDomain;
|
|
maintainers = with lib.maintainers; [ pmiddend ];
|
|
};
|
|
}
|