From 63b308f98b46460ad356aa4aa318ec1c62a43a98 Mon Sep 17 00:00:00 2001
From: Mistyttm <contact@mistyttm.dev>
Date: Thu, 30 Oct 2025 11:08:03 +1000
Subject: [PATCH 1/2] mainters: add schromp

---
 maintainers/maintainer-list.nix | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index ee193d84d31f..cd5db74c377f 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -23219,6 +23219,13 @@
     githubId = 72168352;
     matrix = "@schrobingus:matrix.org";
   };
+  schromp = {
+    email = "schromp@echsen.club";
+    github = "schromp";
+    githubId = 103186360;
+    matrix = "@schromp:echsen.club";
+    name = "schromp";
+  };
   Schweber = {
     github = "Schweber";
     githubId = 64630479;

From 83008f09d9b8636dd29f4fe14f5994cd498b8332 Mon Sep 17 00:00:00 2001
From: Mistyttm <contact@mistyttm.dev>
Date: Thu, 30 Oct 2025 11:08:36 +1000
Subject: [PATCH 2/2] deadlock-modmanager: init at 0.10.1

Co-authored-by: schromp <schromp@echsen.club>
---
 .../disable-update-notice.patch               |  20 +++
 .../no-updater-artifacts.patch                |  12 ++
 .../de/deadlock-mod-manager/package.nix       | 136 ++++++++++++++++++
 3 files changed, 168 insertions(+)
 create mode 100644 pkgs/by-name/de/deadlock-mod-manager/disable-update-notice.patch
 create mode 100644 pkgs/by-name/de/deadlock-mod-manager/no-updater-artifacts.patch
 create mode 100644 pkgs/by-name/de/deadlock-mod-manager/package.nix

diff --git a/pkgs/by-name/de/deadlock-mod-manager/disable-update-notice.patch b/pkgs/by-name/de/deadlock-mod-manager/disable-update-notice.patch
new file mode 100644
index 000000000000..c1eeed4555eb
--- /dev/null
+++ b/pkgs/by-name/de/deadlock-mod-manager/disable-update-notice.patch
@@ -0,0 +1,20 @@
+diff --git a/apps/desktop/src/app.tsx b/apps/desktop/src/app.tsx
+index 70dcbe5ff5..91ac4deb73 100644
+--- a/apps/desktop/src/app.tsx
++++ b/apps/desktop/src/app.tsx
+@@ -68,14 +68,6 @@
+                     <Outlet />
+                   </Layout>
+                   <GlobalPluginRenderer />
+-                  <UpdateDialog
+-                    downloadProgress={downloadProgress}
+-                    isDownloading={isDownloading}
+-                    onOpenChange={handleDismiss}
+-                    onUpdate={handleUpdate}
+-                    open={showUpdateDialog}
+-                    update={update}
+-                  />
+                   <OnboardingWizard
+                     open={showOnboarding}
+                     onComplete={completeOnboarding}
+
diff --git a/pkgs/by-name/de/deadlock-mod-manager/no-updater-artifacts.patch b/pkgs/by-name/de/deadlock-mod-manager/no-updater-artifacts.patch
new file mode 100644
index 000000000000..dd28c3a93fa8
--- /dev/null
+++ b/pkgs/by-name/de/deadlock-mod-manager/no-updater-artifacts.patch
@@ -0,0 +1,12 @@
+diff --git a/apps/desktop/src-tauri/tauri.conf.json b/apps/desktop/src-tauri/tauri.conf.json
+index ed05fce..e1649e0 100644
+--- a/apps/desktop/src-tauri/tauri.conf.json
++++ b/apps/desktop/src-tauri/tauri.conf.json
+@@ -31,7 +31,6 @@
+       }
+     },
+     "active": true,
+-    "createUpdaterArtifacts": true,
+     "targets": "all",
+     "icon": [
+       "icons/32x32.png",
\ No newline at end of file
diff --git a/pkgs/by-name/de/deadlock-mod-manager/package.nix b/pkgs/by-name/de/deadlock-mod-manager/package.nix
new file mode 100644
index 000000000000..9cd54269c38c
--- /dev/null
+++ b/pkgs/by-name/de/deadlock-mod-manager/package.nix
@@ -0,0 +1,136 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  cargo-tauri,
+  nodejs,
+  pnpm_9,
+  pkg-config,
+  wrapGAppsHook3,
+  desktop-file-utils,
+  webkitgtk_4_1,
+  cairo,
+  gdk-pixbuf,
+  glib,
+  glib-networking,
+  gtk3,
+  libsoup_3,
+  pango,
+  openssl,
+  bzip2,
+  gst_all_1,
+  makeDesktopItem,
+  fontconfig,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "deadlock-mod-manager";
+  version = "0.10.1";
+
+  src = fetchFromGitHub {
+    owner = "deadlock-mod-manager";
+    repo = "deadlock-mod-manager";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-/84P9ONG25Ia1BnRcbzQuJKt8HwstCzf0bkx1Xc9VgU=";
+  };
+
+  cargoRoot = "apps/desktop";
+  buildAndTestSubdir = finalAttrs.cargoRoot;
+
+  cargoHash = "sha256-wVsr6GwCGuuveTDT6oS1keejx+y+oSuE6dGAjvNRrdE=";
+
+  nativeBuildInputs = [
+    rustPlatform.cargoSetupHook
+    cargo-tauri.hook
+    nodejs
+    pnpm_9.configHook
+    pkg-config
+    wrapGAppsHook3
+  ];
+
+  buildInputs = [
+    webkitgtk_4_1
+    cairo
+    gdk-pixbuf
+    glib
+    glib-networking
+    gtk3
+    libsoup_3
+    pango
+    openssl
+    bzip2
+    desktop-file-utils
+    gst_all_1.gstreamer
+    gst_all_1.gst-plugins-base
+    gst_all_1.gst-plugins-good
+    gst_all_1.gst-plugins-bad
+  ];
+
+  pnpmRoot = ".";
+  pnpmDeps = pnpm_9.fetchDeps {
+    inherit (finalAttrs)
+      pname
+      version
+      src
+      ;
+    fetcherVersion = 2;
+    sourceRoot = "source";
+    hash = "sha256-7HhMW28hl2hHi8epcKMTbfuVjKYj+U1N/d2tMcu4aQg=";
+  };
+
+  patches = [
+    ./no-updater-artifacts.patch
+    ./disable-update-notice.patch
+  ];
+
+  VITE_API_URL = "https://api.deadlockmods.app";
+
+  # Skip tests that require network access
+  checkFlags = [
+    "--skip=download_manager::downloader::tests::test_download_file"
+  ];
+
+  preFixup = ''
+    gappsWrapperArgs+=(
+      --set FONTCONFIG_FILE "${fontconfig.out}/etc/fonts/fonts.conf"
+      --set TAURI_DIST_DIR "$out/share/deadlock-modmanager/dist"
+      --set WEBKIT_DISABLE_COMPOSITING_MODE 1
+      --set WEBKIT_DISABLE_DMABUF_RENDERER 1
+      --set DISABLE_UPDATE_DESKTOP_DATABASE 1
+      --prefix PATH : ${lib.makeBinPath [ desktop-file-utils ]}
+    )
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      desktopName = "deadlock-mod-manager";
+      name = "Deadlock Mod Manager";
+      exec = "deadlock-mod-manager %u";
+      terminal = false;
+      type = "Application";
+      icon = "deadlock-mod-manager";
+      mimeTypes = [ "x-scheme-handler/deadlock-mod-manager" ];
+      categories = [
+        "Utility"
+        "Game"
+      ];
+    })
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Mod manager for the Valve game Deadlock";
+    homepage = "https://github.com/deadlock-mod-manager/deadlock-mod-manager";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [
+      mistyttm
+      schromp
+    ];
+    platforms = lib.platforms.linux;
+    mainProgram = "deadlock-mod-manager";
+  };
+})