mirror of
https://github.com/torvalds/linux.git
synced 2026-03-07 23:04:33 +01:00
8678591b47
Commit3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") added .modinfo to ELF_DETAILS while removing it from COMMON_DISCARDS, as it was needed in vmlinux.unstripped and ELF_DETAILS was present in all architecture specific vmlinux linker scripts. While this shuffle is fine for vmlinux, ELF_DETAILS and COMMON_DISCARDS may be used by other linker scripts, such as the s390 and x86 compressed boot images, which may not expect to have a .modinfo section. In certain circumstances, this could result in a bootloader failing to load the compressed kernel [1]. Commitddc6cbef3e("s390/boot/vmlinux.lds.S: Ensure bzImage ends with SecureBoot trailer") recently addressed this for the s390 bzImage but the same bug remains for arm, parisc, and x86. The presence of .modinfo in the x86 bzImage was the root cause of the issue worked around with commitd50f210913("kbuild: align modinfo section for Secureboot Authenticode EDK2 compat"). misc.c in arch/x86/boot/compressed includes lib/decompress_unzstd.c, which in turn includes lib/xxhash.c and its MODULE_LICENSE / MODULE_DESCRIPTION macros due to the STATIC definition. Split .modinfo out from ELF_DETAILS into its own macro and handle it in all vmlinux linker scripts. Discard .modinfo in the places where it was previously being discarded from being in COMMON_DISCARDS, as it has never been necessary in those uses. Cc: stable@vger.kernel.org Fixes:3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") Reported-by: Ed W <lists@wildgooses.com> Closes: https://lore.kernel.org/587f25e0-a80e-46a5-9f01-87cb40cfa377@wildgooses.com/ [1] Tested-by: Ed W <lists@wildgooses.com> # x86_64 Link: https://patch.msgid.link/20260225-separate-modinfo-from-elf-details-v1-1-387ced6baf4b@kernel.org Signed-off-by: Nathan Chancellor <nathan@kernel.org>
120 lines
2.5 KiB
ArmAsm
120 lines
2.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
#include <asm/vmlinux.lds.h>
|
|
#include <asm/page.h>
|
|
|
|
OUTPUT_FORMAT(ELF_FORMAT)
|
|
OUTPUT_ARCH(ELF_ARCH)
|
|
ENTRY(_start)
|
|
jiffies = jiffies_64;
|
|
|
|
VERSION {
|
|
{
|
|
local: *;
|
|
};
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
/* This must contain the right address - not quite the default ELF one.*/
|
|
PROVIDE (__executable_start = START);
|
|
/* Static binaries stick stuff here, like the sigreturn trampoline,
|
|
* invisibly to objdump. So, just make __binary_start equal to the very
|
|
* beginning of the executable, and if there are unmapped pages after this,
|
|
* they are forever unusable.
|
|
*/
|
|
__binary_start = START;
|
|
|
|
. = START + SIZEOF_HEADERS;
|
|
. = ALIGN(PAGE_SIZE);
|
|
|
|
_text = .;
|
|
INIT_TEXT_SECTION(0)
|
|
|
|
.text :
|
|
{
|
|
_stext = .;
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
*(.fixup)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.gnu.linkonce.t*)
|
|
}
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
.syscall_stub : {
|
|
__syscall_stub_start = .;
|
|
*(.__syscall_stub*)
|
|
__syscall_stub_end = .;
|
|
}
|
|
|
|
/*
|
|
* These are needed even in a static link, even if they wind up being empty.
|
|
* Newer glibc needs these __rel{,a}_iplt_{start,end} symbols.
|
|
*/
|
|
.rel.plt : {
|
|
*(.rel.plt)
|
|
PROVIDE_HIDDEN(__rel_iplt_start = .);
|
|
*(.rel.iplt)
|
|
PROVIDE_HIDDEN(__rel_iplt_end = .);
|
|
}
|
|
.rela.plt : {
|
|
*(.rela.plt)
|
|
PROVIDE_HIDDEN(__rela_iplt_start = .);
|
|
*(.rela.iplt)
|
|
PROVIDE_HIDDEN(__rela_iplt_end = .);
|
|
}
|
|
|
|
#include <asm/common.lds.S>
|
|
|
|
__init_begin = .;
|
|
init.data : { INIT_DATA }
|
|
__init_end = .;
|
|
|
|
.data :
|
|
{
|
|
INIT_TASK_DATA(KERNEL_STACK_SIZE)
|
|
DATA_DATA
|
|
*(.gnu.linkonce.d*)
|
|
CONSTRUCTORS
|
|
}
|
|
.data1 : { *(.data1) }
|
|
.ctors :
|
|
{
|
|
*(.ctors)
|
|
}
|
|
.dtors :
|
|
{
|
|
*(.dtors)
|
|
}
|
|
|
|
.got : { *(.got.plt) *(.got) }
|
|
.eh_frame : { KEEP (*(.eh_frame)) }
|
|
.dynamic : { *(.dynamic) }
|
|
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
|
|
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata : { *(.sdata) }
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
. = ALIGN(PAGE_SIZE);
|
|
__bss_start = .;
|
|
PROVIDE(_bss_start = .);
|
|
SBSS(0)
|
|
BSS(0)
|
|
__bss_stop = .;
|
|
_end = .;
|
|
PROVIDE (end = .);
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
MODINFO
|
|
ELF_DETAILS
|
|
|
|
DISCARDS
|
|
}
|