mirror of
https://github.com/torvalds/linux.git
synced 2026-03-07 23:04:33 +01:00
8678591b47
Commit3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") added .modinfo to ELF_DETAILS while removing it from COMMON_DISCARDS, as it was needed in vmlinux.unstripped and ELF_DETAILS was present in all architecture specific vmlinux linker scripts. While this shuffle is fine for vmlinux, ELF_DETAILS and COMMON_DISCARDS may be used by other linker scripts, such as the s390 and x86 compressed boot images, which may not expect to have a .modinfo section. In certain circumstances, this could result in a bootloader failing to load the compressed kernel [1]. Commitddc6cbef3e("s390/boot/vmlinux.lds.S: Ensure bzImage ends with SecureBoot trailer") recently addressed this for the s390 bzImage but the same bug remains for arm, parisc, and x86. The presence of .modinfo in the x86 bzImage was the root cause of the issue worked around with commitd50f210913("kbuild: align modinfo section for Secureboot Authenticode EDK2 compat"). misc.c in arch/x86/boot/compressed includes lib/decompress_unzstd.c, which in turn includes lib/xxhash.c and its MODULE_LICENSE / MODULE_DESCRIPTION macros due to the STATIC definition. Split .modinfo out from ELF_DETAILS into its own macro and handle it in all vmlinux linker scripts. Discard .modinfo in the places where it was previously being discarded from being in COMMON_DISCARDS, as it has never been necessary in those uses. Cc: stable@vger.kernel.org Fixes:3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") Reported-by: Ed W <lists@wildgooses.com> Closes: https://lore.kernel.org/587f25e0-a80e-46a5-9f01-87cb40cfa377@wildgooses.com/ [1] Tested-by: Ed W <lists@wildgooses.com> # x86_64 Link: https://patch.msgid.link/20260225-separate-modinfo-from-elf-details-v1-1-387ced6baf4b@kernel.org Signed-off-by: Nathan Chancellor <nathan@kernel.org>
94 lines
1.5 KiB
Text
94 lines
1.5 KiB
Text
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* vmlinux.lds.S -- master linker script for m68knommu arch
|
|
*
|
|
* (C) Copyright 2002-2012, Greg Ungerer <gerg@snapgear.com>
|
|
*
|
|
* This linker script is equipped to build either ROM loaded or RAM
|
|
* run kernels.
|
|
*/
|
|
|
|
#if defined(CONFIG_RAMKERNEL)
|
|
#define KTEXT_ADDR CONFIG_KERNELBASE
|
|
#endif
|
|
#if defined(CONFIG_ROMKERNEL)
|
|
#define KTEXT_ADDR CONFIG_ROMSTART
|
|
#define KDATA_ADDR CONFIG_KERNELBASE
|
|
#define LOAD_OFFSET KDATA_ADDR + (ADDR(.text) + SIZEOF(.text))
|
|
#endif
|
|
|
|
#include <asm/page.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
OUTPUT_ARCH(m68k)
|
|
ENTRY(_start)
|
|
|
|
jiffies = jiffies_64 + 4;
|
|
|
|
SECTIONS {
|
|
|
|
#ifdef CONFIG_ROMVEC
|
|
. = CONFIG_ROMVEC;
|
|
.romvec : {
|
|
__rom_start = .;
|
|
_romvec = .;
|
|
*(.romvec)
|
|
*(.data..initvect)
|
|
}
|
|
#endif
|
|
|
|
. = KTEXT_ADDR;
|
|
|
|
_text = .;
|
|
_stext = .;
|
|
.text : {
|
|
HEAD_TEXT
|
|
TEXT_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
*(.fixup)
|
|
. = ALIGN(16);
|
|
}
|
|
_etext = .;
|
|
|
|
#ifdef KDATA_ADDR
|
|
. = KDATA_ADDR;
|
|
#endif
|
|
|
|
_sdata = .;
|
|
RO_DATA(PAGE_SIZE)
|
|
RW_DATA(16, PAGE_SIZE, THREAD_SIZE)
|
|
_edata = .;
|
|
|
|
EXCEPTION_TABLE(16)
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_begin = .;
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
INIT_DATA_SECTION(16)
|
|
PERCPU_SECTION(16)
|
|
.m68k_fixup : {
|
|
__start_fixup = .;
|
|
*(.m68k_fixup)
|
|
__stop_fixup = .;
|
|
}
|
|
.init.data : {
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
}
|
|
|
|
BSS_SECTION(4, 0, 4)
|
|
|
|
_end = .;
|
|
|
|
STABS_DEBUG
|
|
MODINFO
|
|
ELF_DETAILS
|
|
|
|
/* Sections to be discarded */
|
|
DISCARDS
|
|
}
|
|
|