mirror of
https://github.com/torvalds/linux.git
synced 2026-03-08 10:24:45 +01:00
8678591b47
Commit3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") added .modinfo to ELF_DETAILS while removing it from COMMON_DISCARDS, as it was needed in vmlinux.unstripped and ELF_DETAILS was present in all architecture specific vmlinux linker scripts. While this shuffle is fine for vmlinux, ELF_DETAILS and COMMON_DISCARDS may be used by other linker scripts, such as the s390 and x86 compressed boot images, which may not expect to have a .modinfo section. In certain circumstances, this could result in a bootloader failing to load the compressed kernel [1]. Commitddc6cbef3e("s390/boot/vmlinux.lds.S: Ensure bzImage ends with SecureBoot trailer") recently addressed this for the s390 bzImage but the same bug remains for arm, parisc, and x86. The presence of .modinfo in the x86 bzImage was the root cause of the issue worked around with commitd50f210913("kbuild: align modinfo section for Secureboot Authenticode EDK2 compat"). misc.c in arch/x86/boot/compressed includes lib/decompress_unzstd.c, which in turn includes lib/xxhash.c and its MODULE_LICENSE / MODULE_DESCRIPTION macros due to the STATIC definition. Split .modinfo out from ELF_DETAILS into its own macro and handle it in all vmlinux linker scripts. Discard .modinfo in the places where it was previously being discarded from being in COMMON_DISCARDS, as it has never been necessary in those uses. Cc: stable@vger.kernel.org Fixes:3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") Reported-by: Ed W <lists@wildgooses.com> Closes: https://lore.kernel.org/587f25e0-a80e-46a5-9f01-87cb40cfa377@wildgooses.com/ [1] Tested-by: Ed W <lists@wildgooses.com> # x86_64 Link: https://patch.msgid.link/20260225-separate-modinfo-from-elf-details-v1-1-387ced6baf4b@kernel.org Signed-off-by: Nathan Chancellor <nathan@kernel.org>
96 lines
1.7 KiB
ArmAsm
96 lines
1.7 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* ld script to make SuperH Linux kernel
|
|
* Written by Niibe Yutaka and Paul Mundt
|
|
*/
|
|
OUTPUT_ARCH(sh)
|
|
#define RUNTIME_DISCARD_EXIT
|
|
#include <asm/thread_info.h>
|
|
#include <asm/cache.h>
|
|
#include <asm/vmlinux.lds.h>
|
|
|
|
#ifdef CONFIG_PMB
|
|
#define MEMORY_OFFSET 0
|
|
#else
|
|
#define MEMORY_OFFSET __MEMORY_START
|
|
#endif
|
|
|
|
ENTRY(_start)
|
|
SECTIONS
|
|
{
|
|
. = PAGE_OFFSET + MEMORY_OFFSET + PHYSICAL_OFFSET + CONFIG_ZERO_PAGE_OFFSET;
|
|
|
|
_text = .; /* Text and read-only data */
|
|
|
|
.empty_zero_page : AT(ADDR(.empty_zero_page)) {
|
|
*(.empty_zero_page)
|
|
} = 0
|
|
|
|
.text : AT(ADDR(.text)) {
|
|
HEAD_TEXT
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
KPROBES_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
_etext = .; /* End of text section */
|
|
} = 0x0009
|
|
|
|
EXCEPTION_TABLE(16)
|
|
|
|
_sdata = .;
|
|
RO_DATA(PAGE_SIZE)
|
|
RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
|
|
_edata = .;
|
|
|
|
DWARF_EH_FRAME
|
|
|
|
. = ALIGN(PAGE_SIZE); /* Init code and data */
|
|
__init_begin = .;
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
INIT_DATA_SECTION(16)
|
|
|
|
. = ALIGN(4);
|
|
.machvec.init : AT(ADDR(.machvec.init)) {
|
|
__machvec_start = .;
|
|
*(.machvec.init)
|
|
__machvec_end = .;
|
|
}
|
|
|
|
PERCPU_SECTION(L1_CACHE_BYTES)
|
|
|
|
/*
|
|
* .exit.text is discarded at runtime, not link time, to deal with
|
|
* references from __bug_table
|
|
*/
|
|
.exit.text : AT(ADDR(.exit.text)) { EXIT_TEXT }
|
|
.exit.data : AT(ADDR(.exit.data)) { EXIT_DATA }
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
__bss_start = .;
|
|
SBSS(0)
|
|
. = ALIGN(PAGE_SIZE);
|
|
.bss : AT(ADDR(.bss) - LOAD_OFFSET) {
|
|
BSS_FIRST_SECTIONS
|
|
. = ALIGN(PAGE_SIZE);
|
|
*(.bss..page_aligned)
|
|
. = ALIGN(PAGE_SIZE);
|
|
*(.dynbss)
|
|
*(BSS_MAIN)
|
|
*(COMMON)
|
|
. = ALIGN(8);
|
|
}
|
|
__bss_stop = .;
|
|
_end = . ;
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
MODINFO
|
|
ELF_DETAILS
|
|
|
|
DISCARDS
|
|
}
|