mirror of
https://github.com/torvalds/linux.git
synced 2026-03-08 06:24:43 +01:00
8678591b47
Commit3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") added .modinfo to ELF_DETAILS while removing it from COMMON_DISCARDS, as it was needed in vmlinux.unstripped and ELF_DETAILS was present in all architecture specific vmlinux linker scripts. While this shuffle is fine for vmlinux, ELF_DETAILS and COMMON_DISCARDS may be used by other linker scripts, such as the s390 and x86 compressed boot images, which may not expect to have a .modinfo section. In certain circumstances, this could result in a bootloader failing to load the compressed kernel [1]. Commitddc6cbef3e("s390/boot/vmlinux.lds.S: Ensure bzImage ends with SecureBoot trailer") recently addressed this for the s390 bzImage but the same bug remains for arm, parisc, and x86. The presence of .modinfo in the x86 bzImage was the root cause of the issue worked around with commitd50f210913("kbuild: align modinfo section for Secureboot Authenticode EDK2 compat"). misc.c in arch/x86/boot/compressed includes lib/decompress_unzstd.c, which in turn includes lib/xxhash.c and its MODULE_LICENSE / MODULE_DESCRIPTION macros due to the STATIC definition. Split .modinfo out from ELF_DETAILS into its own macro and handle it in all vmlinux linker scripts. Discard .modinfo in the places where it was previously being discarded from being in COMMON_DISCARDS, as it has never been necessary in those uses. Cc: stable@vger.kernel.org Fixes:3e86e4d74c("kbuild: keep .modinfo section in vmlinux.unstripped") Reported-by: Ed W <lists@wildgooses.com> Closes: https://lore.kernel.org/587f25e0-a80e-46a5-9f01-87cb40cfa377@wildgooses.com/ [1] Tested-by: Ed W <lists@wildgooses.com> # x86_64 Link: https://patch.msgid.link/20260225-separate-modinfo-from-elf-details-v1-1-387ced6baf4b@kernel.org Signed-off-by: Nathan Chancellor <nathan@kernel.org>
116 lines
1.9 KiB
ArmAsm
116 lines
1.9 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
|
|
#include <asm/vmlinux.lds.h>
|
|
#include <asm/page.h>
|
|
#include <asm/memory.h>
|
|
|
|
OUTPUT_ARCH(csky)
|
|
ENTRY(_start)
|
|
|
|
#ifndef __cskyBE__
|
|
jiffies = jiffies_64;
|
|
#else
|
|
jiffies = jiffies_64 + 4;
|
|
#endif
|
|
|
|
#define VBR_BASE \
|
|
. = ALIGN(1024); \
|
|
vec_base = .; \
|
|
. += 512;
|
|
|
|
SECTIONS
|
|
{
|
|
. = PAGE_OFFSET + PHYS_OFFSET_OFFSET;
|
|
|
|
_start = .;
|
|
HEAD_TEXT_SECTION
|
|
. = ALIGN(PAGE_SIZE);
|
|
|
|
.text : AT(ADDR(.text) - LOAD_OFFSET) {
|
|
_text = .;
|
|
_stext = .;
|
|
VBR_BASE
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
KPROBES_TEXT
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
} = 0
|
|
_etext = .;
|
|
|
|
/* __init_begin __init_end must be page aligned for free_initmem */
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_begin = .;
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
INIT_DATA_SECTION(PAGE_SIZE)
|
|
PERCPU_SECTION(L1_CACHE_BYTES)
|
|
. = ALIGN(PAGE_SIZE);
|
|
__init_end = .;
|
|
|
|
_sdata = .;
|
|
RO_DATA(PAGE_SIZE)
|
|
RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
|
|
_edata = .;
|
|
|
|
#ifdef CONFIG_HAVE_TCM
|
|
.tcm_start : {
|
|
. = ALIGN(PAGE_SIZE);
|
|
__tcm_start = .;
|
|
}
|
|
|
|
.text_data_tcm FIXADDR_TCM : AT(__tcm_start)
|
|
{
|
|
. = ALIGN(4);
|
|
__stcm_text_data = .;
|
|
*(.tcm.text)
|
|
*(.tcm.rodata)
|
|
#ifndef CONFIG_HAVE_DTCM
|
|
*(.tcm.data)
|
|
#endif
|
|
. = ALIGN(4);
|
|
__etcm_text_data = .;
|
|
}
|
|
|
|
. = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_data_tcm);
|
|
|
|
#ifdef CONFIG_HAVE_DTCM
|
|
#define ITCM_SIZE CONFIG_ITCM_NR_PAGES * PAGE_SIZE
|
|
|
|
.dtcm_start : {
|
|
__dtcm_start = .;
|
|
}
|
|
|
|
.data_tcm FIXADDR_TCM + ITCM_SIZE : AT(__dtcm_start)
|
|
{
|
|
. = ALIGN(4);
|
|
__stcm_data = .;
|
|
*(.tcm.data)
|
|
. = ALIGN(4);
|
|
__etcm_data = .;
|
|
}
|
|
|
|
. = ADDR(.dtcm_start) + SIZEOF(.data_tcm);
|
|
|
|
.tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_tcm)) {
|
|
#else
|
|
.tcm_end : AT(ADDR(.tcm_start) + SIZEOF(.text_data_tcm)) {
|
|
#endif
|
|
. = ALIGN(PAGE_SIZE);
|
|
__tcm_end = .;
|
|
}
|
|
#endif
|
|
|
|
EXCEPTION_TABLE(L1_CACHE_BYTES)
|
|
BSS_SECTION(L1_CACHE_BYTES, PAGE_SIZE, L1_CACHE_BYTES)
|
|
_end = . ;
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
MODINFO
|
|
ELF_DETAILS
|
|
|
|
DISCARDS
|
|
}
|